收藏本站
切换到窄版

杉宫竹苑工作室

 找回密码
 立即注册
搜索
热搜: 活动 交友 discuz
杉宫竹苑工作室»论坛 › 软件封包 › NSIS › 疑难杂症 › NSIS 输入法头文件
返回列表 发新帖
查看: 2391|回复: 0

NSIS 输入法头文件

[复制链接]
Share
发表于 2017-2-26 11:36:40 | 显示全部楼层 |阅读模式

正式会员享受无限制浏览网站功能和高速网盘下载，赶快加入本站吧！

您需要 登录 才可以下载或查看，没有账号？立即注册

x
  1. /*____________________________________________


  4.    [ 输入法信息安装卸载 NSIS 实用函数 ]
  5.       < 头文件: IMEfunc.nsh >

  7.    
  8.    By Engine @ bbs.hanzify.org  2006
  9.    
  10. Email: hesung at qq.com



  14.   * 提供一个通用宏，和两个函数(分别用于安装段落和卸载段落中)调用...

  16.   (1) 宏 InstallIME ( 不需要预声明 )
  17.   (2) 函数 RemoveIME ( 需要预声明 )
  18.   (3) 函数 un.RemoveIME ( 需要预声明 )

  20. ______________________________________________
  21. */

  23. #####################################################################
  24. ##  使用说明： ##
  25. #################

  27. #------------------------------------------------------------------
  28. # 注册输入法功能部分:
  29. # 宏 InstallIME ( 不需要预声明 )
  30. #------------------------------------------------------------------

  32. # 用法:
  33. /****************************
  34. #; 在你的脚本开头包含头文件
  35. !include "IMEfunc.nsh"


  38. #; 在需要的地方插入宏:
  39. !insertmacro InstallIME "输入法ime文件绝对路径" "输入法描述文本"

  41. ;; 例如: !insertmacro InstallIME "$SYSDIR\unispim.ime" "紫光拼音输入法3.0"
  42. *****************************/


  45. #------------------------------------------------------------------
  46. # 反注册输入法功能部分:
  47. # 函数 RemoveIME ( 需要预声明 )
  48. # 函数 un.RemoveIME ( 需要预声明 )
  49. #------------------------------------------------------------------

  51. # 用法:
  52. /****************************
  53. #; 在你的脚本开头包含头文件:
  54. !include "IMEfunc.nsh"

  56. #; 紧接着必须声明用到的函数: (声明卸载程序函数是 ${un.RemoveIME})
  57. ${RemoveIME}

  59. #; 函数调用方法:
  60. Push "输入法ime文件名"
  61. Call RemoveIME

  63. #; 然后应该是一系列删除文件的代码...
  64. *****************************/

  66. # 例如:
  67. /****************************
  68. Push "unispim.ime"
  69. Call RemoveIME
  70. DetailPrint `反注册 $"紫光拼音输入法3.0$" 完成...`

  72. ;; 你自己的一系列删除清理操作..
  73. ; Delete "$SYSDIR\unispim.ime"
  74. ; Delete "$SYSDIR\upengine.dll"
  75. ; RMDir /r "$SYSDIR\IME\Unispim"
  76. ; RMDir /r "$APPDATA\Unispim"
  77. ;; 清理一些注册表项目，等等...
  78. *****************************/


  81. #####################################################################



  85. ;<IMEfunc.nsh> 开始...



  89. !ifndef INC.UNINSTALLIMEFUNC.NSH
  90. !define INC.UNINSTALLIMEFUNC.NSH

  92. !verbose push
  93. !verbose 3

  95. !include    "logiclib.nsh"

  97. ;------------------------------------


  100. !macro InstallIME ARG_IME_FILE ARG_IME_TEXT

  102. IfFileExists ${ARG_IME_FILE} +3
  103.   DetailPrint "注册输入法信息失败：找不到文件$"${ARG_IME_FILE}$"。"
  104.   ;; 主要用于安装程序调试过程...
  105.   Abort
  106. System::Call 'imm32::ImmInstallIME(t `${ARG_IME_FILE}` ,t `${ARG_IME_TEXT}`)'
  107. DetailPrint `注册 $"${ARG_IME_TEXT}$" 完成...`

  109. !macroend


  112. ;------------------------------------


  115. !define RemoveIME `!insertmacro DEF_FUNC_RemoveIME ""`
  116. !define un.RemoveIME `!insertmacro DEF_FUNC_RemoveIME "un."`

  118. ################################
  119. !define INC.USEFULLIB.NSH

  121. /***
  122. 附加说明:

  124. 下面“ 清理输入法热键信息部分” 使用到了
  125. 蓝色网际函数库 Usefullib.nsh 中的 ReadRegBin 函数。

  127. 如当前你的NSIS\include目录中没有Usefullib.nsh，可以尝试这个链接下载
  128. http://forums.winamp.com/attachment.php?s=&postid=2015251
  129. 如果不暂时不方便获取，可以先将上面 !define INC.USEFULLIB.NSH 注释掉...
  130. ***/
  131. ################################

  133. !ifdef INC.USEFULLIB.NSH
  134. !echo "需要包含蓝色网际的实用函数库文件 Usefullib.nsh ..."
  135. !include "Usefullib.nsh"
  136. !endif

  138. !define HKCU_PRELAOD_TEMPKEY `Keyboard Layout\UninstallTempkey`
  139. !define HKML_KEYBOARD_LAYOUT `SYSTEM\CurrentControlSet\Control\Keyboard Layouts`
  140. !define HKML_WINDOWS_VERSION `SOFTWARE\Microsoft\Windows NT\CurrentVersion`
  141. !define HKCU_IME_HOTKEYS     `Control Panel\Input Method\Hot Keys`

  143. !macro DEF_FUNC_RemoveIME ARG_UNFIX

  145. !ifdef INC.USEFULLIB.NSH
  146.   ${${ARG_UNFIX}ReadRegBin} ;;声明usefullib.nsh中的函数
  147. !endif

  149. Function ${ARG_UNFIX}RemoveIME

  151.     Exch $R0 ;;要卸载的IME
  152.     Push $R1
  153.     Push $R2 ;;KBlayout码
  154.     Push $R3

  156.         StrCpy $R1 0
  157.         ${Do}
  158.             EnumRegKey $R2 HKLM "${HKML_KEYBOARD_LAYOUT}" $R1
  159.                 ${IfThen} $R2 == "" ${|} Goto TheEnd ${|}
  160.             ReadRegStr $R3 HKLM "${HKML_KEYBOARD_LAYOUT}\$R2" "IME file"
  161.                 ${IfThen} $R3 == $R0 ${|} ${ExitDo} ${|}
  162.             IntOp $R1 $R1 + 1
  163.         ${Loop}
  164.         StrCpy $R1 "0x$R2"
  165.         System::Call "User32::UnloadKeyboardLayout(i R1) i .R0"

  167.         DeleteRegKey HKLM "${HKML_KEYBOARD_LAYOUT}\$R2"
  168.         StrCpy $R1 1
  169.         ${DO}
  170.             ReadRegStr $R0 HKLM "SYSTEM\ControlSet00$R1\Control" "CurrentUser"
  171.                 ${IfThen} $R0 == "" ${|} ${ExitDo} ${|}
  172.             DeleteRegKey HKLM "SYSTEM\ControlSet00$R1\Control\Keyboard Layouts\$R2"
  173.             IntOp $R1 $R1 + 1
  174.         ${Loop}

  176.         ;;调用TrimPreload处理托盘项目
  177.         Call ${ARG_UNFIX}TrimPreload

  179.         !ifdef INC.USEFULLIB.NSH
  180.         ;;清理输入法热键信息
  181.             StrCpy $R0 ""
  182.             ${ForEach} $R3 0 6 + 2
  183.                     StrCpy $R1 $R2 2 $R3
  184.                     StrCpy $R0 "$R1$R0"
  185.             ${Next} ;;转换编码方式

  187.             StrCpy $R1 0
  188.             ${Do}
  189.                 EnumRegKey $R3 HKCU "${HKCU_IME_HOTKEYS}" $R1
  190.                     ${IfThen} $R3 == "" ${|} ${ExitDo} ${|}
  191.                 ${${ARG_UNFIX}ReadRegBin} $R2 ${HKCU} "${HKCU_IME_HOTKEYS}\$R3" "Target IME"
  192.                     ${If} $R2 == $R0
  193.                         DeleteRegKey HKCU "${HKCU_IME_HOTKEYS}\$R3"
  194.                         ${ExitDo}
  195.                     ${EndIf}
  196.                 IntOp $R1 $R1 + 1
  197.             ${Loop}
  198.         !endif
  199.         TheEnd:

  201.     Pop $R3
  202.     Pop $R2
  203.     Pop $R1
  204.     Pop $R0

  206. FunctionEnd

  208. # X. 函数 TrimPreload :
  209. # X. RemoveIME 的子函数清理输入法预加载-注册表项残余...
  210. Function ${ARG_UNFIX}TrimPreload

  212.     Push $0
  213.     Push $1
  214.     Push $2
  215.     Push $3
  216.     Push $4 ;KBlayout
  217.     Push $5 ;Counter
  218.     Push $6 ;HKL
  219.     Push $7 ;HIWORD
  220.     Push $8 ;LangID
  221.     Push $9 ;DefaultLangID
  222.     Push $R0 ;Windows Version

  224. SetPluginUnload alwaysoff
  225.     System::Call 'user32::GetKeyboardLayout(i 0)i.r0'
  226.         IntFmt $0 "%08x" $0
  227.         StrCpy $9 $0 "" -4
  228.     System::Call 'user32::GetKeyboardLayoutList(i 0, i 0) i .r3'
  229.         IntOp $3 $3 * 4
  230.     System::Alloc $3
  231.         Pop $2
  232.     System::Call 'user32::GetKeyboardLayoutList(i r3, i r2) i .r0'
  233.         IntCmp 1 $0 0 0 TheEnd

  235.     ClearErrors
  236.     ReadRegStr $R0 HKLM "${HKML_WINDOWS_VERSION}" CurrentVersion
  237.         IfErrors 0 +2
  238.         StrCpy $R0 "Win9X"
  239.     DeleteRegKey HKCU "Keyboard Layout\Preload"
  240.     DeleteRegKey HKCU "Keyboard Layout\Substitutes"

  242.     IntOp $3 $2 + $3
  243.     IntOp $3 $3 - 4
  244.     ${ForEach} $2 $2 $3 + 4
  245.         System::Call '*$2(i .r0)'
  246.         IntFmt $6 "%08x" $0
  247.         StrCpy $8 $6 "" -4
  248.         StrCpy $7 $6 4
  249.             ReadRegStr $5 HKCU "${HKCU_PRELAOD_TEMPKEY}\$8\Preload" ""
  250.             IntOp $5 $5 + 1
  251.         ${If} $8 == $7
  252.             StrCpy $4 "0000$8"
  253.             WriteRegStr HKCU "${HKCU_PRELAOD_TEMPKEY}\$8\Preload" "" $5
  254.             WriteRegStr HKCU "${HKCU_PRELAOD_TEMPKEY}\$8\Preload" $5 $4
  255.             ${Continue}
  256.         ${EndIf}
  257.         StrCpy $0 $6 1
  258.         ${Switch} $0
  259.             ${Case} 'e'
  260.                 StrCpy $4 $6
  261.                 WriteRegStr HKCU "${HKCU_PRELAOD_TEMPKEY}\$8\Preload" "" $5
  262.                 WriteRegStr HKCU "${HKCU_PRELAOD_TEMPKEY}\$8\Preload" $5 $4
  263.                 ${Break}
  264.             ${Case} 'f'
  265.                 IntOp $7 0x$7 & 0x0fff
  266.                 IntFmt $7 "%04x" $7
  267.                 StrCpy $1 0
  268.                 ${Do}
  269.                     EnumRegKey $4 HKLM "${HKML_KEYBOARD_LAYOUT}" $1
  270.                         ${IfThen} $4 == "" ${|} ${ExitDo} ${|}
  271.                     ReadRegStr $0 HKLM "${HKML_KEYBOARD_LAYOUT}\$4" "Layout Id"
  272.                         ${IfThen} $0 == $7 ${|} Goto Default ${|}
  273.                     IntOp $1 $1 + 1
  274.                 ${Loop}
  275.                 ${Break}
  276.             ${CaseElse}
  277.                 StrCpy $4 "0000$6" 8
  278.                 Default:
  279.                 ReadRegStr $0 HKCU "${HKCU_PRELAOD_TEMPKEY}\$8" ""
  280.                 IntOp $1 0x$0 + 0xd000
  281.                 IntFmt $1 "%04x" $1
  282.                 IntOp $0 $0 + 1
  283.                 WriteRegStr HKCU "${HKCU_PRELAOD_TEMPKEY}\$8" "" $0
  284.                 ${If} $R0 == "Win9X"
  285.                     WriteRegStr HKCU "Keyboard Layout\Substitutes\$1$8" "" $4
  286.                 ${Else}
  287.                     WriteRegStr HKCU "Keyboard Layout\Substitutes" "$1$8" $4
  288.                 ${EndIf}
  289.                 WriteRegStr HKCU "${HKCU_PRELAOD_TEMPKEY}\$8\Preload" "" $5
  290.                 WriteRegStr HKCU "${HKCU_PRELAOD_TEMPKEY}\$8\Preload" $5 "$1$8"
  291.         ${EndSwitch}
  292.     ${Next}

  294.     StrCpy $1 1
  295.     ${Do}
  296.         ${If} $1 == 1
  297.             StrCpy $8 $9
  298.         ${Else}
  299.             EnumRegKey $8 HKCU "${HKCU_PRELAOD_TEMPKEY}" 0
  300.             ${If} $8 == ""
  301.                 DeleteRegKey HKCU "${HKCU_PRELAOD_TEMPKEY}"
  302.                 ${ExitDo}
  303.             ${EndIf}
  304.         ${EndIf}
  305.         ReadRegStr $5 HKCU "${HKCU_PRELAOD_TEMPKEY}\$8\Preload" ""
  306.         ${For} $0 1 $5
  307.             ReadRegStr $6 HKCU "${HKCU_PRELAOD_TEMPKEY}\$8\Preload" $0
  308.             ${If} $R0 == "Win9X"
  309.                 WriteRegStr HKCU "Keyboard Layout\Preload\$1" "" $6
  310.             ${Else}
  311.                 WriteRegStr HKCU "Keyboard Layout\Preload" $1 $6
  312.             ${EndIf}
  313.             IntOp $1 $1 + 1
  314.         ${Next}
  315.         DeleteRegKey HKCU "${HKCU_PRELAOD_TEMPKEY}\$8"
  316.     ${Loop}
  317.     TheEnd:
  318. SetPluginUnload manual
  319. System::Free $0
  320.    
  321.     Pop $R0
  322.     Pop $9
  323.     Pop $8
  324.     Pop $7
  325.     Pop $6
  326.     Pop $5
  327.     Pop $4
  328.     Pop $3
  329.     Pop $2
  330.     Pop $1
  331.     Pop $0

  333. FunctionEnd

  335. !macroend # DEF_FUNC_RemoveIME

  337. !verbose pop
  338. !endif # INC.UNINSTALLIMEFUNC.NSH



  342. ;复制保存为保存为IMEfunc.nsh
复制代码


输入法

相关帖子
回复

使用道具 举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

QQ|小黑屋|手机版|Archiver|SgzyStudio

GMT+8, 2024-5-19 15:51 , Processed in 0.113380 second(s), 22 queries .

Powered by Discuz! X3.4

© 2001-2023 Discuz! Team.

快速回复 返回顶部 返回列表