NSIS添加删除功能组件

Share

脚本

下面的例子会根据你在组件页的选择在Windows桌面上创建子目录 "Component One", "Component Two", 等等。
请编译后，多运行几次，通过改变组件的选项，以查看不同的结果。
如果有更好的方法来改进，请和 [url=]ts2001@hotbox.ru[/url]联系。
如果在你的安装程序里使用它：
1、在你的脚本开头复制并粘贴系统宏，或者直接引用文件。
2、在卸载区块前复制并粘贴回调函数，确保你为每个可选项在命令区块指定区块索引的输出常量。
3、在SectionList macro列出你的可选区块，为每个区块使用下面的格式（替换下面的section_index）。

!insertmacro "${MacroName}" "section_index"

4、在每个可选区块后写上 Remove_${section_index}宏，该宏必须描述删除区块。
下面是添加删除功能的一个简单代码。

1. ;--- Add/Remove system macros: ---
   
2. ; (可以调用头文件来代替这些)
   
3. Var AR_SecFlags
   
4. Var AR_RegFlags
   
5. 
   
6. !macro InitSection SecName
   
7.   ;  This macro reads component installed flag from the registry and
   
8.   ;changes checked state of the section on the components page.
   
9.   ;Input: section index constant name specified in Section command.
   
10. 
    
11.   ClearErrors
    
12.   ;Reading component status from registry
    
13.   ReadRegDWORD $AR_RegFlags HKLM \
    
14.     "${REG_UNINSTALL}\Components\${SecName}" "Installed"
    
15.   IfErrors "default_${SecName}"
    
16.     ;Status will stay default if registry value not found
    
17.     ;(component was never installed)
    
18.   IntOp $AR_RegFlags $AR_RegFlags & 0x0001  ;Turn off all other bits
    
19.   SectionGetFlags ${${SecName}} $AR_SecFlags  ;Reading default section flags
    
20.   IntOp $AR_SecFlags $AR_SecFlags & 0xFFFE  ;Turn lowest (enabled) bit off
    
21.   IntOp $AR_SecFlags $AR_RegFlags | $AR_SecFlags      ;Change lowest bit
    
22. 
    
23.   ;Writing modified flags
    
24.   SectionSetFlags ${${SecName}} $AR_SecFlags
    
25. 
    
26. "default_${SecName}:"
    
27. !macroend
    
28. 
    
29. !macro FinishSection SecName
    
30.   ;  This macro reads section flag set by user and removes the section
    
31.   ;if it is not selected.
    
32.   ;Then it writes component installed flag to registry
    
33.   ;Input: section index constant name specified in Section command.
    
34. 
    
35.   SectionGetFlags ${${SecName}} $AR_SecFlags  ;Reading section flags
    
36.   ;Checking lowest bit:
    
37.   IntOp $AR_SecFlags $AR_SecFlags & 0x0001
    
38.   IntCmp $AR_SecFlags 1 "leave_${SecName}"
    
39.     ;Section is not selected:
    
40.     ;Calling Section uninstall macro and writing zero installed flag
    
41.     !insertmacro "Remove_${${SecName}}"
    
42.     WriteRegDWORD HKLM "${REG_UNINSTALL}\Components\${SecName}" \
    
43.   "Installed" 0
    
44.     Goto "exit_${SecName}"
    
45. 
    
46. "leave_${SecName}:"
    
47.     ;Section is selected:
    
48.     WriteRegDWORD HKLM "${REG_UNINSTALL}\Components\${SecName}" \
    
49.   "Installed" 1
    
50. 
    
51. "exit_${SecName}:"
    
52. !macroend
    
53. 
    
54. !macro RemoveSection SecName
    
55.   ;  This macro is used to call section's Remove_... macro
    
56.   ;from the uninstaller.
    
57.   ;Input: section index constant name specified in Section command.
    
58. 
    
59.   !insertmacro "Remove_${${SecName}}"
    
60. !macroend
    
61. ;--- End of Add/Remove macros ---
    
62. 
    
63. 
    
64. ;  This constant specifies the installer file name.
    
65. !define InstFile "AddRemove.exe"
    
66. OutFile "${InstFile}"
    
67. 
    
68. ;  This constant specifies Windows uninstall key for your application.
    
69. !define REG_UNINSTALL "Software\Microsoft\Windows\CurrentVersion\Uninstall\
    
70. \AddRemoveExample"
    
71. 
    
72. InstallDir "$DESKTOP\AddRemove Example"
    
73. Name "Add/Remove Example 1.0"
    
74. ComponentText "Check the components you want to add and uncheck \
    
75. the components you want to remove:"
    
76. ShowInstDetails show
    
77. ShowUnInstDetails show
    
78. 
    
79. 
    
80. Section "Required Section"
    
81. SectionIn RO
    
82.   ;This section is required. It can't be removed.
    
83. 
    
84.   CreateDirectory $INSTDIR
    
85.   WriteUninstaller "$INSTDIR\Uninstall.exe"
    
86. 
    
87. ;Writing uninstall info to registry:
    
88.   WriteRegStr HKLM "${REG_UNINSTALL}" "DisplayName" "Add/Remove Example"
    
89.   WriteRegStr HKLM "${REG_UNINSTALL}" "DisplayIcon" "$INSTDIR\Uninstall.exe"
    
90.   WriteRegStr HKLM "${REG_UNINSTALL}" "DisplayVersion" "1.0"
    
91.   WriteRegStr HKLM "${REG_UNINSTALL}" "Publisher" "THRaSH"
    
92.   WriteRegStr HKLM "${REG_UNINSTALL}" "InstallSource" "$EXEDIR"
    
93. 
    
94.   ;Under WinXP this creates two separate buttons: "Modify" and "Remove".
    
95.   ;"Modify" will run installer and "Remove" will run uninstaller.
    
96.   WriteRegDWord HKLM "${REG_UNINSTALL}" "NoModify" 0
    
97.   WriteRegDWord HKLM "${REG_UNINSTALL}" "NoRepair" 0
    
98.   WriteRegStr HKLM "${REG_UNINSTALL}" "UninstallString" \
    
99. '"$INSTDIR\Uninstall.exe"'
    
100.   WriteRegStr HKLM "${REG_UNINSTALL}" "ModifyPath" '"$EXEDIR\${InstFile}"'
     
101. SectionEnd
     
102. 
     
103. Section "Component One (selected by default)" sec_One
     
104.   ;Installs component one
     
105.   ;By default this section is selected
     
106.   DetailPrint "*** Adding Component One..."
     
107.   CreateDirectory "$INSTDIR\Component One"
     
108. SectionEnd
     
109. !macro Remove_${sec_One}
     
110.   ;Removes component one
     
111.   DetailPrint "*** Removing Component One..."
     
112.   RMDir /r "$INSTDIR\Component One"
     
113. !macroend
     
114. 
     
115. Section /o "Component Two (unselected by default)" sec_Two
     
116.   ;Installs component two
     
117.   ;By default this section is not selected
     
118.   DetailPrint "*** Adding Component Two..."
     
119.   CreateDirectory "$INSTDIR\Component Two"
     
120. SectionEnd
     
121. !macro Remove_${sec_Two}
     
122.   ;Removes component two
     
123.   DetailPrint "*** Removing Component Two..."
     
124.   RMDir /r "$INSTDIR\Component Two"
     
125. !macroend
     
126. 
     
127. Section /o "Component Three (unselected by default)" sec_Three
     
128.   ;Installs component three
     
129.   ;By default this section is not selected
     
130.   DetailPrint "*** Adding Component Three..."
     
131.   CreateDirectory "$INSTDIR\Component Three"
     
132. SectionEnd
     
133. !macro Remove_${sec_Three}
     
134.   ;Removes component three
     
135.   DetailPrint "*** Removing Component Three..."
     
136.   RMDir /r "$INSTDIR\Component Three"
     
137. !macroend
     
138. 
     
139. 
     
140. ;--- Add/Remove callback functions: ---
     
141. !macro SectionList MacroName
     
142.   ;This macro used to perform operation on multiple sections.
     
143.   ;List all of your components in following manner here.
     
144. 
     
145.   !insertmacro "${MacroName}" "sec_One"
     
146.   !insertmacro "${MacroName}" "sec_Two"
     
147.   !insertmacro "${MacroName}" "sec_Three"
     
148. !macroend
     
149. 
     
150. Function .onInit
     
151.   ;Reads components status for registry
     
152.   !insertmacro SectionList "InitSection"
     
153. FunctionEnd
     
154. 
     
155. Section -FinishComponents
     
156.   ;Removes unselected components and writes component status to registry
     
157.   !insertmacro SectionList "FinishSection"
     
158. SectionEnd
     
159. 
     
160. Section -Post
     
161.   ;Showing the results
     
162.   ExecShell "open" "$INSTDIR"
     
163. SectionEnd
     
164. ;--- End of Add/Remove callback functions ---
     
165. 
     
166. 
     
167. Section Uninstall
     
168.   ;First removes all optional components
     
169.   !insertmacro SectionList "RemoveSection"
     
170. 
     
171.   ;Removes directory and registry key:
     
172.   RMDIR /r $INSTDIR
     
173.   DeleteRegKey HKLM "${REG_UNINSTALL}"
     
174. SectionEnd

复制代码