通过读取kernel32.dll获取系统版本

Share

1. ################################################################################
   
2. ### 注意：早期版本 (包括 2.46 官方版) 的 System 插件不支持 p 类型，需改为 i。
   
3. ### 例如：pR1、p.R2、p${VS_VERSION_INFO} 等，改为 iR1、i.R2、i${VS_VERSION_INFO}
   
4. ### 如果修改后结果仍为 0，请尝试使用最新 2.46.x、3.0 等版本的 System.dll 插件。
   
5. ################################################################################
   
6. !ifndef RT_VERSION
   
7. !define RT_VERSION      16
   
8. !endif
   
9. !ifndef VS_FILE_INFO
   
10. !define VS_FILE_INFO    ${RT_VERSION}
    
11. !endif
    
12. !ifndef VS_VERSION_INFO
    
13. !define VS_VERSION_INFO 1
    
14. !endif
    
15. 
    
16. # 获取真正的系统版本号
    
17. Function GetRealOSVersion
    
18.     Push $R0
    
19.     Push $R1
    
20.     Push $R2
    
21.     Push $R3
    
22.     Push $R4
    
23.     Push $R5
    
24.     Push $R6
    
25.     StrCpy $R0 0
    
26.     System::Call 'kernel32::LoadLibrary(t"kernel32.dll")p.R1'
    
27.     IntCmp $R1 0 _ver_err_done
    
28.     System::Call 'kernel32::FindResource(pR1,p${VS_VERSION_INFO},p${VS_FILE_INFO})p.R2'
    
29.     IntCmp $R2 0 _ver_err_free
    
30.     System::Call 'kernel32::LoadResource(pR1,pR2)p.R3'
    
31.     IntCmp $R3 0 _ver_err_free
    
32.     System::Call 'kernel32::LockResource(pR3)p.R4'
    
33.     IntCmp $R4 0 _ver_err_free
    
34.     System::Call "*$R4(&i2,&i2.R5,&i2,&w16,&i2,i,i,i.R6)"
    
35.     IntCmp $R5 0 _ver_err_free
    
36.     IntFmt $R0 "0x%08X" $R6
    
37. _ver_err_free:
    
38.     System::Call "kernel32::FreeLibrary(pR1)"
    
39. _ver_err_done:
    
40.     Pop $R6
    
41.     Pop $R5
    
42.     Pop $R4
    
43.     Pop $R3
    
44.     Pop $R2
    
45.     Pop $R1
    
46.     Exch $R0
    
47. FunctionEnd
    
48. ################################################################################
    
49. ################################################################################
    
50. !AddPluginDir .
    
51. 
    
52. Name WinVer
    
53. OutFile WinVer.exe
    
54. InstallDir $TEMP
    
55. 
    
56. XPStyle on
    
57. InstallColors /windows
    
58. ShowInstDetails show
    
59. RequestExecutionLevel admin
    
60. 
    
61. Page instfiles
    
62. 
    
63. Section -Main
    
64.     # 0x00050000  5.0  Windows 2000
    
65.     # 0x00050001  5.1  Windows XP
    
66.     # 0x00050002  5.2  Windows XP (x64), Windows Server 2003, Windows Server 2003 R2
    
67.     # 0x00060000  6.0  Windows Vista,    Windows Server 2008
    
68.     # 0x00060001  6.1  Windows 7,        Windows Server 2008 R2
    
69.     # 0x00060002  6.2  Windows 8,        Windows Server 2012
    
70.     # 0x00060003  6.3  Windows 8.1,      Windows Server 2012 R2
    
71.     # 0x000A0000  10.0 Windows 10,       Windows Server Technical Preview
    
72. 
    
73.     Call GetRealOSVersion
    
74.     Pop $R0
    
75.     # 如果结果为 0 请参考本文件顶部说明
    
76.     DetailPrint "$R0"
    
77. 
    
78.     IntOp $0 $R0 >> 16
    
79.     IntOp $1 $R0 & 0xFFFF
    
80.     DetailPrint "$0.$1"
    
81. SectionEnd

复制代码

完整脚本附件下载
RealOSVer.zip

Share

1. ################################################################################
   
2. ### 注意：早期版本 (包括 2.46 官方版) 的 System 插件不支持 p 类型，需改为 i。
   
3. ### 例如：pR1、p.R2、p${VS_VERSION_INFO} 等，改为 iR1、i.R2、i${VS_VERSION_INFO}
   
4. ### 如果修改后结果仍为 0，请尝试使用最新 2.46.x、3.0 等版本的 System.dll 插件。
   
5. ################################################################################
   
6. Function GetRealOSVersion
   
7.     Push $R0
   
8.     Push $R1
   
9.     Push $R2
   
10.     Push $R3
    
11.     Push $R4
    
12.     StrCpy $R0 0
    
13.     System::Call "netapi32::NetWkstaGetInfo(pn,i100,*p.R1)i.R2"
    
14.     StrCmp $R2 0 0 +5
    
15.     System::Call "*$R1(i,p,p,i.R3,i.R4)"
    
16.     # $R3 是主版本号，如 Windows 7 就是 6
    
17.     # $R4 是次版本号，如 Windows 7 就是 1
    
18.     # 这里将其组合为 DWORD 即 32 位整数
    
19.     IntOp $R0 $R3 << 16
    
20.     IntOp $R0 $R0 | $R4
    
21.     System::Call "netapi32::NetApiBufferFree(pR1)"
    
22.     # 将结果格式化为十六进制表示法
    
23.     IntFmt $R0 "0x%08X" $R0
    
24.     Pop $R4
    
25.     Pop $R3
    
26.     Pop $R2
    
27.     Pop $R1
    
28.     Exch $R0
    
29. FunctionEnd
    
30. ################################################################################
    
31. ################################################################################
    
32. !AddPluginDir .
    
33. 
    
34. Name WinVer
    
35. OutFile WinVer.exe
    
36. InstallDir $TEMP
    
37. 
    
38. XPStyle on
    
39. InstallColors /windows
    
40. ShowInstDetails show
    
41. RequestExecutionLevel admin
    
42. 
    
43. Page instfiles
    
44. 
    
45. Section -Main
    
46.     # 0x00050000  5.0  Windows 2000
    
47.     # 0x00050001  5.1  Windows XP
    
48.     # 0x00050002  5.2  Windows XP (x64), Windows Server 2003, Windows Server 2003 R2
    
49.     # 0x00060000  6.0  Windows Vista,    Windows Server 2008
    
50.     # 0x00060001  6.1  Windows 7,        Windows Server 2008 R2
    
51.     # 0x00060002  6.2  Windows 8,        Windows Server 2012
    
52.     # 0x00060003  6.3  Windows 8.1,      Windows Server 2012 R2
    
53.     # 0x000A0000  10.0 Windows 10,       Windows Server Technical Preview
    
54. 
    
55.     Call GetRealOSVersion
    
56.     Pop $R0
    
57.     # 如果结果为 0 请参考本文件顶部说明
    
58.     DetailPrint "$R0"
    
59. 
    
60.     # 分离主次版本号
    
61.     IntOp $0 $R0 >> 16
    
62.     IntOp $1 $R0 & 0xFFFF
    
63.     DetailPrint "$0.$1"
    
64. SectionEnd

复制代码

完整脚本附件下载
RealOSVer2.zip