收藏本站
切换到窄版

杉宫竹苑工作室

 找回密码
 立即注册
搜索
热搜: 活动 交友 discuz
杉宫竹苑工作室»论坛 › 软件封包 › NSIS › 脚本示例 › Nsis 安装脚本示例
返回列表 发新帖
查看: 2029|回复: 0

Nsis 安装脚本示例

[复制链接]
Share
发表于 2016-9-2 20:08:53 | 显示全部楼层 |阅读模式

正式会员享受无限制浏览网站功能和高速网盘下载，赶快加入本站吧！

您需要 登录 才可以下载或查看，没有账号？立即注册

x
  1. ${PRODUCT_NAME}; 安装程序初始定义常量
  2. !define PRODUCT_NAME "软件名"
  3. !define PRODUCT_VERSION "1.0"
  4. !define PRODUCT_WEB_SITE "http://www.google.com"
  5. !define PRODUCT_DIR_REGKEY "Software\Microsoft\Windows\CurrentVersion\App Paths\${PRODUCT_NAME}.exe"
  6. !define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
  7. !define PRODUCT_UNINST_ROOT_KEY "HKLM"
  8. !define PRODUCT_STARTMENU_REGVAL "NSIS:StartMenuDir"

  10. SetCompressor /SOLID lzma
  11. SetCompressorDictSize 32

  13. ; ------ MUI 现代界面定义 (1.67 版本以上兼容) ------
  14. !include "MUI.nsh"

  16. ; MUI 预定义常量
  17. !define MUI_ABORTWARNING ;当用户要关闭安装程序时, 显示一个警告消息框
  18. !define MUI_UNABORTWARNING ;当用户要关闭卸载程序时, 显示一个警告消息框
  19. !define MUI_ICON "install.ico" ;安装程序图标
  20. !define MUI_UNICON "uninst.ico" ;卸载程序图标
  21. !define MUI_FINISHPAGE_NOAUTOCLOSE ;不自动跳到完成页面, 允许用户检查安装记录
  22. !define MUI_UNFINISHPAGE_NOAUTOCLOSE ;不自动跳到完成页面, 允许用户检查卸载记录
  23. !define MUI_WELCOMEFINISHPAGE_BITMAP "welcome.bmp" ;用于欢迎页面和完成页面的位图(推荐尺寸: 164x314 象素).
  24. !define MUI_UNWELCOMEFINISHPAGE_BITMAP "welcome.bmp" ;用于卸载页面的位图(推荐尺寸: 164x314 象素).
  25. !define MUI_COMPONENTSPAGE_SMALLDESC ;较小的页面底部的描述区域
  26. !define MUI_COMPONENTSPAGE_TEXT_DESCRIPTION_INFO "鼠标移到组件上可查看相应说明" ;当没有选择区段时, 显示于描述框中的文本

  28. ; 欢迎页面
  29. !insertmacro MUI_PAGE_WELCOME
  30. ; 组件选择页面
  31. !insertmacro MUI_PAGE_COMPONENTS
  32. ; 安装目录选择页面
  33. !insertmacro MUI_PAGE_DIRECTORY
  34. ; 开始菜单设置页面
  35. var ICONS_GROUP
  36. !define MUI_STARTMENUPAGE_NODISABLE
  37. !define MUI_STARTMENUPAGE_DEFAULTFOLDER "${PRODUCT_NAME}"
  38. !define MUI_STARTMENUPAGE_REGISTRY_ROOT "${PRODUCT_UNINST_ROOT_KEY}"
  39. !define MUI_STARTMENUPAGE_REGISTRY_KEY "${PRODUCT_UNINST_KEY}"
  40. !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "${PRODUCT_STARTMENU_REGVAL}"
  41. !insertmacro MUI_PAGE_STARTMENU Application $ICONS_GROUP
  42. ; 安装过程页面
  43. !insertmacro MUI_PAGE_INSTFILES
  44. ; 安装完成页面
  45. !define MUI_FINISHPAGE_RUN "$INSTDIR\${PRODUCT_NAME}.exe"
  46. !define MUI_FINISHPAGE_RUN_NOTCHECKED ;默认不选中 '运行程序' 复选框
  47. !define MUI_FINISHPAGE_SHOWREADME "$INSTDIR\Readme.txt"
  48. !define MUI_FINISHPAGE_SHOWREADME_NOTCHECKED ;默认不选中 '自述文件' 复选框
  49. !define MUI_FINISHPAGE_LINK "【欢迎访问作者主页】"
  50. !define MUI_FINISHPAGE_LINK_LOCATION "${PRODUCT_WEB_SITE}"
  51. !insertmacro MUI_PAGE_FINISH

  53. ; 安装卸载过程页面
  54. !insertmacro MUI_UNPAGE_INSTFILES

  56. ; 安装界面包含的语言设置
  57. !insertmacro MUI_LANGUAGE "SimpChinese"
  58. !insertmacro MUI_LANGUAGE "English"

  60. ; 安装预释放文件
  61. !insertmacro MUI_RESERVEFILE_INSTALLOPTIONS
  62. ; ------ MUI 现代界面定义结束 ------


  65. Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
  66. OutFile "Setup.exe"
  67. InstallDir "$PROGRAMFILES\${PRODUCT_NAME}"
  68. InstallDirRegKey HKLM "${PRODUCT_UNINST_KEY}" "UninstallString"
  69. ShowInstDetails hide ;设置是否显示安装详细信息
  70. ShowUnInstDetails hide
  71. BrandingText "作者："

  73. Section "!主程序" SEC01
  74. SectionIn RO ;必选组件灰色
  75.   SetOutPath "$INSTDIR"
  76.   SetOverwrite on
  77.   File "Readme.txt"

  79. ; 创建开始菜单快捷方式
  80.   !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
  81.   CreateShortCut "$DESKTOP\${PRODUCT_NAME}.lnk" "$INSTDIR\${PRODUCT_NAME}.exe"
  82.   CreateDirectory "$SMPROGRAMS\$ICONS_GROUP"
  83.   CreateShortCut "$SMPROGRAMS\$ICONS_GROUP\${PRODUCT_NAME}.lnk" "$INSTDIR\${PRODUCT_NAME}.exe"
  84.   !insertmacro MUI_STARTMENU_WRITE_END
  85. SectionEnd

  87. ; 安装.NET Framework
  88. Section "Microsoft .NET Framework 2.0" SEC02
  89.   File "DotNet.exe"
  90.   ExecWait '"DotNet.exe" /q:a /c:"install.exe /q"'
  91. SectionEnd

  93. Section -AdditionalIcons
  94.   !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
  95.   WriteIniStr "$INSTDIR\${PRODUCT_NAME}.url" "InternetShortcut" "URL" "${PRODUCT_WEB_SITE}"
  96.   CreateShortCut "$SMPROGRAMS\$ICONS_GROUP\欢迎访问作者主页.lnk" "$INSTDIR\${PRODUCT_NAME}.url"
  97.   CreateShortCut "$SMPROGRAMS\$ICONS_GROUP\卸载.lnk" "$INSTDIR\uninst.exe"
  98.   !insertmacro MUI_STARTMENU_WRITE_END
  99. SectionEnd

  101. Section -Post
  102.   WriteUninstaller "$INSTDIR\uninst.exe"
  103.   WriteRegStr HKLM "${PRODUCT_DIR_REGKEY}" "" "$INSTDIR\${PRODUCT_NAME}.exe"
  104.   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
  105.   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
  106.   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayIcon" "$INSTDIR\${PRODUCT_NAME}.exe"
  107.   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
  108.   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${PRODUCT_WEB_SITE}"
  109. SectionEnd

  111. #-- 根据 NSIS 脚本编辑规则，所有 Function 区段必须放置在 Section 区段之后编写，以避免安装程序出现未可预知的问题。--#

  113. ; 区段组件描述
  114. !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
  115.   !insertmacro MUI_DESCRIPTION_TEXT ${SEC01} "必备组件"
  116.   !insertmacro MUI_DESCRIPTION_TEXT ${SEC02} "运行主程序必需的框架，如果确认已经安装，则不必勾选"
  117. !insertmacro MUI_FUNCTION_DESCRIPTION_END

  119. /******************************
  120. *  以下是安装程序的卸载部分  *
  121. ******************************/

  123. Section Uninstall
  124.   !insertmacro MUI_STARTMENU_GETFOLDER "Application" $ICONS_GROUP
  125.   Delete "$INSTDIR\uninst.exe"

  127.   Delete "$DESKTOP\${PRODUCT_NAME}.lnk"
  128.   
  129.   SetShellVarContext current ;当前用户开始菜单
  130.   Delete "$SMPROGRAMS\$ICONS_GROUP\卸载.lnk"
  131.   Delete "$SMPROGRAMS\$ICONS_GROUP\${PRODUCT_NAME}.lnk"
  132.   Delete "$SMPROGRAMS\$ICONS_GROUP\欢迎访问作者主页.lnk"
  133.   RMDir /r "$SMPROGRAMS\$ICONS_GROUP"
  134.     SetShellVarContext all ;全部用户开始菜单
  135.   Delete "$SMPROGRAMS\$ICONS_GROUP\卸载.lnk"
  136.   Delete "$SMPROGRAMS\$ICONS_GROUP\${PRODUCT_NAME}.lnk"
  137.   Delete "$SMPROGRAMS\$ICONS_GROUP\欢迎访问作者主页.lnk"
  138.   
  139.   RMDir /r "$SMPROGRAMS\$ICONS_GROUP"

  141.   RMDir /r "$INSTDIR"

  143.   DeleteRegKey ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}"
  144.   DeleteRegKey HKLM "${PRODUCT_DIR_REGKEY}"
  145.   SetAutoClose false
  146. SectionEnd

  148. #-- 根据 NSIS 脚本编辑规则，所有 Function 区段必须放置在 Section 区段之后编写，以避免安装程序出现未可预知的问题。--#

  150. Function un.onInit
  151.   MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "您确实要完全移除 $(^Name) ，及其所有的组件？" IDYES +2
  152.   Abort
  153. FunctionEnd

  155. Function un.onUninstSuccess
  156.   HideWindow
  157.   MessageBox MB_ICONINFORMATION|MB_OK "$(^Name) 已成功地从您的计算机移除。"
  158. FunctionEnd
复制代码


回复

使用道具 举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

QQ|小黑屋|手机版|Archiver|SgzyStudio

GMT+8, 2024-5-19 20:01 , Processed in 0.100419 second(s), 18 queries .

Powered by Discuz! X3.4

© 2001-2023 Discuz! Team.

快速回复 返回顶部 返回列表