NSIS 使用技巧精品集合

Share

实现组件的选择安装，很适合新手！


!define MUI_PAGE_CUSTOMFUNCTION_Pre ComponentsPre
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_INSTFILES

!insertmacro MUI_LANGUAGE "Simpchinese"

Section "组件A" SecA
SectionEnd

Section "组件B" SecB
SectionEnd

Section "组件C" SecC
SectionEnd

游客，如果您要查看本帖隐藏内容请回复

[Settings]
NumFields=7

[Field 1]
Type=label
Text=SQLServer 连接?
Left=0
Right=-1
Top=0
Bottom=9

[Field 2]
Type=Text
Left=40
Right=163
Top=22
Bottom=35

[Field 3]
Type=Text
Left=39
Right=163
Top=43
Bottom=54

[Field 4]
Type=Password
Left=39
Right=163
Top=62
Bottom=75

[Field 5]
Type=Label
Text=密码:
Left=8
Right=36
Top=65
Bottom=75

[Field 6]
Type=Label
Text=账号:
Left=8
Right=38
Top=46
Bottom=56

[Field 7]
Type=Label
Text=服务器:
Left=6
Right=34
Top=27
Bottom=36


如何把安装的卸载程序放到其他目录
问题： 如何把卸载程序放到其他地方而能够正常卸载安装的软件。

当因为特殊原因要把卸载程序写到系统的其他目录时，我们会认为直接就是把 uninst.exe 放到其他目录就可以了，但是实际上，NSIS 在卸载时 $INSTDIR 是指向 uninst.exe 的当前目录的。所以我写了一个例子，首先，用向导生成一个基本脚本，然后修改，以下红色注释的行为修改过的。

; 该脚本使用 HM VNISEdit 脚本编辑器向导产生

; 安装程序初始定义常量
!define PRODUCT_NAME "testapp"
!define PRODUCT_VERSION "1.0"
!define PRODUCT_PUBLISHER "test, Inc."
!define PRODUCT_WEB_SITE "http://testapp.com"
!define PRODUCT_DIR_REGKEY "Software\Microsoft\Windows\CurrentVersion\App Paths\testapp.exe"
!define PRODUCT_REGKEY "Software\testapp" # 创建注册表自己程序的键
!define PRODUCT_UNINST_KEY"Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
!define PRODUCT_UNINST_ROOT_KEY "HKLM"

Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
OutFile "Setup.exe"
LoadLanguageFile "${NSISDIR}\Contrib\Language files\SimpChinese.nlf"
InstallDir "$PROGRAMFILES\testapp"
Icon "${NSISDIR}\Contrib\Graphics\Icons\modern-install.ico"
UninstallIcon "${NSISDIR}\Contrib\Graphics\Icons\modern-uninstall.ico"
InstallDirRegKey HKLM "${PRODUCT_UNINST_KEY}" "UninstallString"
DirText "安装程序将安装 $(^Name) 在下列文件夹。$\r$\n$\r$\n要安装在不同文件夹，单击 [浏览] 并选择其他文件夹。"
ShowInstDetails show
ShowUnInstDetails show

Section "MainSection" SEC01
SetOutPath "$INSTDIR"
SetOverwrite ifnewer
File "/oname=testapp.exe" "C:\Program Files\NSIS\NSIS.exe" # 把 NSIS.exe 改名作为测试例子程序
createDirectory "$SMPROGRAMS\测试安装"
createShortCut "$SMPROGRAMS\测试安装\testapp.lnk" "$INSTDIR\testapp.exe"
SectionEnd

Section -AdditionalIcons
createShortCut "$SMPROGRAMS\测试安装\Uninstall.lnk" "$WINDIR\uninst_testapp.exe" # 卸载程序的路径也要改
SectionEnd

Section -Post
WriteUninstaller "$WINDIR\uninst_testapp.exe" # 把卸载程序放到了 "C:\Windows" ，注意，放到可能造成重复文件的地方，一定要把卸载程序改为特殊的名字，防止给另外的卸载程序覆盖。
WriteRegStr HKLM "${PRODUCT_DIR_REGKEY}" "" "$INSTDIR\testapp.exe"
WriteRegStr HKLM "${PRODUCT_REGKEY}" "" "$INSTDIR" # 写入安装时的安装路径。
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$WINDIR\uninst_testapp.exe" # 卸载程序的路径也要改
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayIcon" "$INSTDIR\testapp.exe"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${PRODUCT_WEB_SITE}"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "Publisher" "${PRODUCT_PUBLISHER}"
SectionEnd

Function un.onUninstSuccess
HideWindow
MessageBox MB_ICONINFORMATION|MB_OK "$(^Name) 已成功地从你的计算机移除。"
FunctionEnd

Function un.onInit
MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "你确实要完全移除 $(^Name) ，其及所有的组件？" IDYES +2
Abort
FunctionEnd

Section Uninstall
ReadRegStr $INSTDIR HKLM "${PRODUCT_REGKEY}" ""
# 在注册表中强行读入安装路径到变量 $INSTDIR，因为卸载程序默认只认为自己所在路径为 $INSTDIR 路径
delete "$WINDIR\uninst_testapp.exe" # 卸载程序的路径也要改
delete "$INSTDIR\testapp.exe"

delete "$SMPROGRAMS\测试安装\Uninstall.lnk"
delete "$SMPROGRAMS\测试安装\testapp.lnk"

RMDir "$SMPROGRAMS\测试安装"

RMDir "$INSTDIR"

deleteRegKey ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}"
deleteRegKey HKLM "${PRODUCT_DIR_REGKEY}"
SetAutoClose true
SectionEnd


关于如何打破 NSIS 的 8192 字节限制
所以我写了个插件。打破这个限制。如下：下载插件，附插件源码，里面有例子脚本。在这里先附上例子脚本。
----已找到更加简单的方法来实现这个功能，请看 [关于打破 NSIS 的 8192 字节限制的更简单方法]
---- 这里作为一个功能测试的另类方法吧。

/*----------------------------------------------/
/ 关于 NSIS 自定义控件写入超过 8192 字节的插件。/
/ 理论上如果控件能够容纳，多大的文本都能放入 /
/----------------------------------------------*/

!include "MUI.nsh"

Name "test"
OutFile "Setup.exe"

SetCompressor lzma ; 设置 lzma 压缩方式

Var hwnd ; 自定义页面的窗口句柄

Page custom PageInitFunc PageLeaveFunc # 自定义页面
!insertmacro MUI_PAGE_INSTFILES

!insertmacro MUI_LANGUAGE "SimpChinese" # 设置安装界面语言

ReserveFile "io.ini" # 预先打包文件，方便安装加速释放 io.ini
ReserveFile "license.txt" # 预先打包文件，方便安装加速释放 io.ini

Function .onInit
InitPluginsDir
File "/oname=$PLUGINSDIR\io.ini" "io.ini" ; 释放 io.ini 文件
File "/oname=$PLUGINSDIR\license.txt" "license.txt" ; 释放 license.txt 文件
FunctionEnd

Function PageInitFunc
InstallOptions::initDialog /NOUNLOAD "$PLUGINSDIR\io.ini"
Pop $hwnd ; 获取自定义页面的窗口句柄
GetDlgItem $1 $hwnd 1200 ; 控件句柄获取公式 (1200 + field 1 - 1)
nsExStr::SetWindowText $1 "$PLUGINSDIR\license.txt" ; 写入一个超过 8012 字节的文件到一个控件，我这里写入的是一个超过 30KB 的文本文件。理论上大小没有限制，只要控件能够接受多大，它就能有多大。
InstallOptions::show ; 显示自定义页面
Pop $0
FunctionEnd

Function PageLeaveFunc
FunctionEnd

Section "sec a" SEC1
SectionEnd


[Settings]
NumFields=1

[Field 1]
Type=Text
Flags=MULTILINE|VSCROLL
State=Text
Left=2
Right=299
Top=3
Bottom=137


nsExStr::SetWindowText 调用格式：
nsExStr::SetWindowText [控件窗口句柄] [想加入控件中的文本文件]
返回值： $0 如果是 0 是正常返回，如果是 1 则执行错误。
抛弃那个 NSIS 的编译特别版吧，实在是限制多多，最大也不过是 8192 字节，对于我来说，那是不能满足的。
有了这个插件，你将可以在任何的控件中放入超大文本，你可以预先打包文件，例如协议之类的文本文件，也可以动态写入一个文本文件，然后调用这个插件来把文本写入一个控件
本来如果这个控件用 VC++ 来写可以很小的，无奈偶的 VC++ 本事实在太差，而 Delphi 的代码却是如此的简单，在 exdll.dll 的基础上只加了不到 10 句，这是 VC++ 无法相比的。而且相信在 lzma 的强大压缩之下，当安装文件越来越大时，这个损耗会越来越小。
尽管如此，偶测试过，用 lzma 算法压缩，安装程序只增加了 28 KB 不到。我想如果要我在 VC++ 里面大费周章，我想我还是增加 28 KB 字节算了。

使用方法：把 nsExStr.dll 文件放到 plugins 中，然后就可以像调用其他插件那样做了。
插件下载： http://restools.hanzify.org/nsis/nsExStr.zip

关于打破 NSIS 的 8192 字节限制的更简单方法
上次那个要做一个插件，花去了二十几个 KB，对于更加节省资源，这里提供一个更简单的方法，无需插件。生成安装文件更加的小。
看来偶的功力还有待提升，否则每次做无用功，还真是无趣呢~~

/*----------------------------------------------/
/ 关于 NSIS 自定义控件写入超过 8192 字节的插件。/
/ 理论上如果控件能够容纳，多大的文本都能放入 /
/----------------------------------------------*/

!include "MUI.nsh"
!include "LogicLib.nsh"

Name "test"
OutFile "Setup.exe"

SetCompressor lzma ; 设置 lzma 压缩方式

Var hwnd ; 自定义页面的窗口句柄

Page custom PageInitFunc "" # 自定义页面
!insertmacro MUI_PAGE_INSTFILES # 安装过程页面

!insertmacro MUI_LANGUAGE "SimpChinese" # 设置安装界面语言

ReserveFile "io.ini" # 预先打包文件，方便安装加速释放
ReserveFile "license.txt" # 预先打包文件，方便安装加速释放

Function .onInit
InitPluginsDir
File "/oname=$PLUGINSDIR\io.ini" "io.ini" ; 释放 io.ini 文件
File "/oname=$PLUGINSDIR\license.txt" "license.txt" ; 释放 license.txt 文件，该文件是一个超过 30 KB 的文本文件
FunctionEnd

Function PageInitFunc
InstallOptions::initDialog /NOUNLOAD "$PLUGINSDIR\io.ini"
Pop $hwnd ; 获取自定义页面的窗口句柄
GetDlgItem $1 $hwnd 1200 ; 控件句柄获取公式 (1200 + field 1 - 1)
Push "$PLUGINSDIR\license.txt" # 在堆栈中压入 大文本文件
Push $1 # 在堆栈中压入 控件句柄
Call ShowText # 调用过程，在控件中加入大文本
InstallOptions::show ; 显示自定义页面
Pop $0
FunctionEnd

Function ShowText
# 如果你对程序设计不熟悉，那么你可以不用理解这个过程，把它复制到你的脚本中就可以了。
Exch $R0 ;控件句柄
Exch
Exch $R1 ;文件
Push $R2
Push $R3
Push $R4
Push $R5

ClearErrors
FileOpen $R2 $R1 r ;$R2 = 文件句柄
${Unless} ${Errors} ;确保打开文件没有发生错误
System::Call /NOUNLOAD "Kernel32::GetFileSize(i, i) i (R2, 0) .R3" ;$R3 = 文件大小
IntOp $R3 $R3 + 1
System::Alloc /NOUNLOAD $R3 ;分配内存
Pop $R4 ;内存地址
${If} $R4 U> 0 ;确保分配了内存
System::Call /NOUNLOAD "*(i 0) i .R5"
System::Call /NOUNLOAD `Kernel32::ReadFile(i, i, i, i, i) i (R2, R4R4, R3, R5R5, 0)`
System::Call /NOUNLOAD "*$R5(i .R1)"
${If} $R1 > 0
System::Call /NOUNLOAD "User32::SendMessage(i, i, i, i) i (R0, ${WM_SETTEXT}, 0, R4)"
${EndIf}
System::Free /NOUNLOAD $R5
System::Free $R4 ;释放内存
${EndIf}
FileClose $R2
${EndUnless}

Pop $R5
Pop $R4
Pop $R3
Pop $R2
Pop $R1
Pop $R0
FunctionEnd

Section "sec a" SEC1
SectionEnd


[Settings]
NumFields=1

[Field 1]
Type=Text
Flags=MULTILINE|VSCROLL
State=Text
Left=2
Right=299
Top=3
Bottom=137