汉化补丁安装包脚本

admin

1. ; Script generated by the HM NIS Edit Script Wizard.
   
2. SetCompressor lzma
   
3. 
   
4. ; HM NIS Edit Wizard helper defines
   
5. !define PRODUCT_NAME "BattleMoonWars银 简体中文版"
   
6. !define PRODUCT_VERSION "1.0b"
   
7. !define PRODUCT_PUBLISHER "SOS团·POPGO 超☆总支部 宝马计划"
   
8. !define PRODUCT_DIR_REGKEY "Software\Microsoft\Windows\CurrentVersion\App Paths\bmw3_chs"
   
9. !define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
   
10. !define PRODUCT_UNINST_ROOT_KEY "HKLM"
    
11. !define PRODUCT_STARTMENU_REGVAL "NSIS:StartMenuDir"
    
12. 
    
13. ; MUI 1.67 compatible ------
    
14. !include "MUI.nsh"
    
15. !include "FileFunc.nsh"
    
16. !insertmacro DirState
    
17. 
    
18. ; MUI Settings
    
19. !define MUI_ABORTWARNING
    
20. !define MUI_ICON "K:\dev\bmw3_install_pack\res\sos_logo.ico"
    
21. !define MUI_UNICON "K:\dev\bmw3_install_pack\res\sos_logo.ico"
    
22. 
    
23. ; Language Selection Dialog Settings
    
24. !define MUI_LANGDLL_REGISTRY_ROOT "${PRODUCT_UNINST_ROOT_KEY}"
    
25. !define MUI_LANGDLL_REGISTRY_KEY "${PRODUCT_UNINST_KEY}"
    
26. !define MUI_LANGDLL_REGISTRY_VALUENAME "NSIS:Language"
    
27. 
    
28. ; Welcome page
    
29. !insertmacro MUI_PAGE_WELCOME
    
30. ; License page
    
31. !define MUI_LICENSEPAGE_CHECKBOX
    
32. !insertmacro MUI_PAGE_LICENSE "K:\dev\bmw3_install_pack\license.txt"
    
33. ; Directory page
    
34. !insertmacro MUI_PAGE_DIRECTORY
    
35. ; Start menu page
    
36. var /GLOBAL ICONS_GROUP
    
37. !define MUI_STARTMENUPAGE_DEFAULTFOLDER "SOS团·POPGO 超☆总支部 宝马计划"
    
38. !define MUI_STARTMENUPAGE_REGISTRY_ROOT "${PRODUCT_UNINST_ROOT_KEY}"
    
39. !define MUI_STARTMENUPAGE_REGISTRY_KEY "${PRODUCT_UNINST_KEY}"
    
40. !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "${PRODUCT_STARTMENU_REGVAL}"
    
41. !insertmacro MUI_PAGE_STARTMENU Application $ICONS_GROUP
    
42. ; Instfiles page
    
43. !insertmacro MUI_PAGE_INSTFILES
    
44. ; Finish page
    
45. !define MUI_FINISHPAGE_RUN "$INSTDIR\bmw_chs.exe"
    
46. !insertmacro MUI_PAGE_FINISH
    
47. 
    
48. ; Uninstaller pages
    
49. !insertmacro MUI_UNPAGE_INSTFILES
    
50. 
    
51. ; Language files
    
52. !insertmacro MUI_LANGUAGE "SimpChinese"
    
53. VIProductVersion "1.0.0.0"
    
54. VIAddVersionKey /LANG=2052 "FileDescription" "${PRODUCT_NAME}"
    
55. ;VIAddVersionKey /LANG=2052 "Comments" "${PRODUCT_WEB_SITE}"
    
56. VIAddVersionKey /LANG=2052 "ProductName" "${PRODUCT_NAME}"
    
57. VIAddVersionKey /LANG=2052 "LegalCopyright" ""
    
58. VIAddVersionKey /LANG=2052 "CompanyName" "${PRODUCT_PUBLISHER}"
    
59. VIAddVersionKey /LANG=2052 "FileVersion" "${PRODUCT_VERSION}"
    
60. 
    
61. ReserveFile "res\logo.bmp"
    
62. 
    
63. ; MUI end ------
    
64. 
    
65. Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
    
66. OutFile "BMW3patch_zh-cn.exe"
    
67. InstallDir "$EXEDIR"
    
68. InstallDirRegKey HKLM "${PRODUCT_DIR_REGKEY}" ""
    
69. ShowInstDetails show
    
70. ShowUnInstDetails show
    
71. 
    
72. Var /GLOBAL tempStr
    
73. Var /GLOBAL length
    
74. Function .onInit
    
75.   InitPluginsDir
    
76.   File "/oname=$PLUGINSDIR\Splash_Splash.bmp" "res\logo.bmp"
    
77.   ; 使用闪屏插件显示闪屏
    
78.   advsplash::show 1500 600 400 -1 "$PLUGINSDIR\Splash_Splash"
    
79.   Pop $0 ; $0 返回 '1' 表示用户提前关闭闪屏, 返回 '0' 表示闪屏正常结束, 返回 '-1' 表示闪屏显示出错
    
80.   ;!insertmacro MUI_LANGDLL_DISPLAY
    
81.   ReadRegStr $tempStr HKLM "${PRODUCT_DIR_REGKEY}" ""
    
82.   StrCmp $tempStr "" nopreviousinstall previouslyinstalled
    
83.   previouslyinstalled:
    
84.     Delete "$SMPROGRAMS\\BattleMoonWars银 简体中文版.lnk"
    
85.     Delete "$DESKTOP\BattleMoonWars银 简体中文版.lnk"
    
86.     StrLen $length "$tempStr"
    
87.     IntOp $length $length - 11
    
88.     StrCpy $INSTDIR "$tempStr" $length
    
89.   nopreviousinstall:
    
90. FunctionEnd
    
91. 
    
92. Var /GLOBAL hasBackup
    
93. Var /GLOBAL dirStatus
    
94. 
    
95. Section "MainSection" SEC01
    
96. ;-------------------------backup----------------------------
    
97.   ReadRegStr $hasBackup ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "hasBackup"
    
98.   StrCmp $hasBackup "true" next askRestore
    
99.   askRestore:
    
100.     MessageBox MB_ICONQUESTION|MB_YESNO "是否备份原始文件? (需要大约6.5M左右的硬盘空间)$\r$\n注意：不备份原始文件则无法在卸载汉化补丁后直接恢复为原游戏。" IDYES true IDNO false
     
101.     true:
     
102.       DetailPrint "正在备份文件..."
     
103.       StrCpy $hasBackup "true"
     
104.       CreateDirectory "$INSTDIR\backup"
     
105.       SetOverwrite on
     
106.       SetOutPath "$INSTDIR\backup"
     
107.       File "K:\dev\bmw3_install_pack\backup\backup_070614b.bak"
     
108.       Goto next
     
109.     false:
     
110.       StrCpy $hasBackup "false"
     
111.   next:
     
112. ;--------------------------copy----------------------------
     
113.   SetOutPath "$INSTDIR"
     
114.   DetailPrint "正在复制文件..."
     
115.   SetOverwrite ifnewer
     
116.   File "K:\dev\bmw3_install_pack\data\bmw_chs.exe"
     
117.   Delete "$INSTDIR\bmw.exe"
     
118.   SetOverwrite on
     
119.   File "K:\dev\bmw3_install_pack\data\config.exe"
     
120.   File "K:\dev\bmw3_install_pack\data\data1.dat"
     
121.   File "K:\dev\bmw3_install_pack\data\data3.dat"
     
122.   File "K:\dev\bmw3_install_pack\data\data5.dat"
     
123.   File "K:\dev\bmw3_install_pack\data\data7.dat"
     
124.   File "K:\dev\bmw3_install_pack\data\data8_2.dat"
     
125.   File "K:\dev\bmw3_install_pack\data\data_chs.dat"
     
126.   File "K:\dev\bmw3_install_pack\readme_chs.txt"
     
127.   File "K:\dev\bmw3_install_pack\data\Manual.exe"
     
128.   ExecWait '"$INSTDIR\Manual.exe"'
     
129.   Delete "$INSTDIR\Manual.exe"
     
130.   Delete "$INSTDIR\マニュアル.html"
     
131.   ${DirState} "$INSTDIR\savedata" $dirStatus
     
132.   StrCmp $dirStatus "-1" nosavedata donesavedata
     
133.   nosavedata:
     
134.     CreateDirectory "$INSTDIR\savedata"
     
135.   donesavedata:
     
136. SectionEnd
     
137. 
     
138. Section "Add Start Menu Shortcuts" SEC02
     
139.   ; shortcuts
     
140.   !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
     
141.   SetOutPath "$INSTDIR"
     
142.   CreateDirectory "$SMPROGRAMS\$ICONS_GROUP"
     
143.   CreateShortCut "$SMPROGRAMS\$ICONS_GROUP\BattleMoonWars银 简体中文版.lnk" "$INSTDIR\bmw_chs.exe"
     
144.   CreateShortCut "$SMPROGRAMS\$ICONS_GROUP\BattleMoonWars银 启动设置.lnk" "$INSTDIR\config.exe"
     
145.   CreateShortCut "$SMPROGRAMS\$ICONS_GROUP\BattleMoonWars银 游戏手册.lnk" "$INSTDIR\Manual.html"
     
146.   CreateShortCut "$DESKTOP\BattleMoonWars银 简体中文版.lnk" "$INSTDIR\bmw_chs.exe"
     
147.   CreateShortCut "$DESKTOP\BattleMoonWars银 启动设置.lnk" "$INSTDIR\config.exe"
     
148.   CreateShortCut "$DESKTOP\BattleMoonWars银 游戏手册.lnk" "$INSTDIR\Manual.html"
     
149.   !insertmacro MUI_STARTMENU_WRITE_END
     
150. SectionEnd
     
151. 
     
152. Section -AdditionalIcons
     
153.   !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
     
154.   CreateShortCut "$SMPROGRAMS\$ICONS_GROUP\卸载简体中文补丁.lnk" "$INSTDIR\uninst.exe"
     
155.   !insertmacro MUI_STARTMENU_WRITE_END
     
156. SectionEnd
     
157. 
     
158. Section -Post
     
159.   WriteUninstaller "$INSTDIR\uninst.exe"
     
160.   WriteRegStr HKLM "${PRODUCT_DIR_REGKEY}" "" "$INSTDIR\bmw_chs.exe"
     
161.   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
     
162.   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
     
163.   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayIcon" "$INSTDIR\bmw_chs.exe"
     
164.   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
     
165.   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "Publisher" "${PRODUCT_PUBLISHER}"
     
166.   StrCmp $hasBackup "true" writeTrue writeFalse
     
167.   writeTrue:
     
168.     WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "hasBackup" "true"
     
169.     Goto writeDone
     
170.   writeFalse:
     
171.     WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "hasBackup" "false"
     
172.   writeDone:
     
173. SectionEnd
     
174. 
     
175. 
     
176. Function un.onUninstSuccess
     
177.   HideWindow
     
178.   MessageBox MB_ICONINFORMATION|MB_OK "「BattleMoonWars银 简体中文版」已成功地从你的计算机删除。"
     
179. FunctionEnd
     
180. 
     
181. Function un.onInit
     
182. !insertmacro MUI_UNGETLANGUAGE
     
183.   MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "你确实要完全删除「BattleMoonWars银 简体中文版」，其及所有組件？" IDYES +2
     
184.   Abort
     
185. FunctionEnd
     
186. 
     
187. Section Uninstall
     
188.   !insertmacro MUI_STARTMENU_GETFOLDER "Application" $ICONS_GROUP
     
189. ;----------------------delete_files------------------------
     
190.   Delete "$INSTDIR\uninst.exe"
     
191.   Delete "$INSTDIR\data1.dat"
     
192.   Delete "$INSTDIR\data3.dat"
     
193.   Delete "$INSTDIR\data5.dat"
     
194.   Delete "$INSTDIR\data7.dat"
     
195.   Delete "$INSTDIR\data_chs.dat"
     
196.   Delete "$INSTDIR\config.exe"
     
197.   Delete "$INSTDIR\bmw_chs.exe"
     
198.   Delete "$INSTDIR\readme_chs.txt"
     
199.   Delete "$INSTDIR\Manual.html"
     
200. ;--------------------delete_shortcuts----------------------
     
201.   Delete "$SMPROGRAMS\$ICONS_GROUP\BattleMoonWars银 简体中文版.lnk"
     
202.   Delete "$SMPROGRAMS\$ICONS_GROUP\BattleMoonWars银 启动设置.lnk"
     
203.   Delete "$SMPROGRAMS\$ICONS_GROUP\BattleMoonWars银 游戏手册.lnk"
     
204.   Delete "$SMPROGRAMS\$ICONS_GROUP\卸载简体中文补丁.lnk"
     
205.   Delete "$DESKTOP\BattleMoonWars银 简体中文版.lnk"
     
206.   Delete "$DESKTOP\BattleMoonWars银 启动设置.lnk"
     
207.   Delete "$DESKTOP\BattleMoonWars银 游戏手册.lnk"
     
208. ;------------------restore_backup_files--------------------
     
209.   RMDir "$SMPROGRAMS\$ICONS_GROUP"
     
210.   Var /GLOBAL testBackup
     
211.   ReadRegStr $testBackup ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "hasBackup"
     
212.   StrCmp $testBackup "true" restoreBackup noRestore
     
213.   restoreBackup:
     
214.     SetOverwrite on
     
215.     CopyFiles "$INSTDIR\backup\backup_070614b.bak" "$INSTDIR"
     
216.     RMDir /r "$INSTDIR\backup"
     
217.     Rename "$INSTDIR\backup_070614b.bak" "$INSTDIR\backup_070614b.exe"
     
218.     ;nsExec::ExecToStack '"$INSTDIR\backup_070614b.exe"'
     
219.     ExecWait '"$INSTDIR\backup_070614b.exe"'
     
220.     Delete "$INSTDIR\backup_070614b.exe"
     
221.   noRestore:
     
222. ;-----------------delete_uninst_reg_keys-------------------
     
223.   DeleteRegKey ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}"
     
224.   DeleteRegKey HKLM "${PRODUCT_DIR_REGKEY}"
     
225. ;--------------------close_after_unist---------------------
     
226.   SetAutoClose true
     
227. SectionEnd

复制代码

这个脚本十分直观,几乎就做了文件复制/删除而已.有趣的地方在我实现备份的那部分,我是把070614版的升级补丁整个做成了一个自解压的WinZip压缩包,并将后缀改为bak,根据需要保存在游戏目录的backup子目录里.然后,在卸载这个汉化补丁时,将那个升级补丁的后缀改回来并执行解压,最后删除掉它.很取巧吧 =_=||