简体中文汉化版安装包

admin

需求：
1、需要做splash
2、需要添加左侧的图片
3、需要播放背景音乐
4、需要备份若干个原始文件

显示splash图像用的是NSIS自带的一个splash plugin。这个跟BMW那个补丁里用的一样。
播放背景音乐则用到了nsisbass插件。这个插件下载下来之后文件都混在了一起，要自己把.nsh文件复制到NSIS的%NSISDIR%\include目录里，并且把bass.dll复制到%NSISDIR%\Contrib\nsisbass目录里。

1. ; Script generated by the HM NIS Edit Script Wizard.
   
2. SetCompressor lzma
   
3. 
   
4. ; HM NIS Edit Wizard helper defines
   
5. !define PRODUCT_NAME "更胜黎明前的琉璃色 汉化补丁"
   
6. !define PRODUCT_VERSION "1.1"
   
7. !define PRODUCT_PUBLISHER "月桂琉璃汉化组"
   
8. !define PRODUCT_DIR_REGKEY "Software\Microsoft\Windows\CurrentVersion\App Paths\yoake_chs"
   
9. !define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
   
10. !define PRODUCT_UNINST_ROOT_KEY "HKLM"
    
11. !define PRODUCT_STARTMENU_REGVAL "NSIS:StartMenuDir"
    
12. 
    
13. ; MUI 1.67 compatible ------
    
14. !include "MUI.nsh"
    
15. !define MUI_WELCOMEFINISHPAGE_BITMAP ".\bmp\inst.bmp"
    
16. !include "FileFunc.nsh"
    
17. !include "nsisbass.nsh"
    
18. !include "nsisbassmacros.nsh"
    
19. !insertmacro DirState
    
20. 
    
21. ; MUI Settings
    
22. !define MUI_ABORTWARNING
    
23. !define MUI_ICON ".\icon\yak966464.ico"
    
24. !define MUI_UNICON ".\icon\yak966464.ico"
    
25. 
    
26. ; Language Selection Dialog Settings
    
27. !define MUI_LANGDLL_REGISTRY_ROOT "${PRODUCT_UNINST_ROOT_KEY}"
    
28. !define MUI_LANGDLL_REGISTRY_KEY "${PRODUCT_UNINST_KEY}"
    
29. !define MUI_LANGDLL_REGISTRY_VALUENAME "NSIS:Language"
    
30. 
    
31. ; Welcome page
    
32. !insertmacro MUI_PAGE_WELCOME
    
33. ; License page
    
34. !define MUI_LICENSEPAGE_CHECKBOX
    
35. !insertmacro MUI_PAGE_LICENSE ".\txt\License.txt"
    
36. ; Directory page
    
37. !insertmacro MUI_PAGE_DIRECTORY
    
38. ; Start menu page
    
39. var /GLOBAL ICONS_GROUP
    
40. !define MUI_STARTMENUPAGE_DEFAULTFOLDER "月桂琉璃汉化组"
    
41. !define MUI_STARTMENUPAGE_REGISTRY_ROOT "${PRODUCT_UNINST_ROOT_KEY}"
    
42. !define MUI_STARTMENUPAGE_REGISTRY_KEY "${PRODUCT_UNINST_KEY}"
    
43. !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "${PRODUCT_STARTMENU_REGVAL}"
    
44. !insertmacro MUI_PAGE_STARTMENU Application $ICONS_GROUP
    
45. ; Instfiles page
    
46. !insertmacro MUI_PAGE_INSTFILES
    
47. ; Finish page
    
48. !define MUI_FINISHPAGE_RUN "$INSTDIR\BGI_CHS.exe"
    
49. !insertmacro MUI_PAGE_FINISH
    
50. 
    
51. ; Uninstaller pages
    
52. !insertmacro MUI_UNPAGE_INSTFILES
    
53. 
    
54. ; Language files
    
55. !insertmacro MUI_LANGUAGE "SimpChinese"
    
56. VIProductVersion "1.0.0.0"
    
57. VIAddVersionKey /LANG=2052 "FileDescription" "${PRODUCT_NAME}"
    
58. VIAddVersionKey /LANG=2052 "ProductName" "${PRODUCT_NAME}"
    
59. VIAddVersionKey /LANG=2052 "LegalCopyright" ""
    
60. VIAddVersionKey /LANG=2052 "CompanyName" "${PRODUCT_PUBLISHER}"
    
61. VIAddVersionKey /LANG=2052 "FileVersion" "${PRODUCT_VERSION}"
    
62. 
    
63. ReserveFile ".\bmp\splash.bmp"
    
64. ReserveFile "${NSISDIR}\Plugins\system.dll"
    
65. ReserveFile ".\bass.dll"
    
66. ReserveFile ".\music\bgm.mp3"
    
67. 
    
68. ; MUI end ------
    
69. 
    
70. Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
    
71. OutFile "yoake_patch_chs.exe"
    
72. InstallDir "$EXEDIR"
    
73. InstallDirRegKey HKLM "${PRODUCT_DIR_REGKEY}" ""
    
74. ShowInstDetails show
    
75. ShowUnInstDetails show
    
76. 
    
77. Function .onInit
    
78.   InitPluginsDir
    
79.   File "/oname=$PLUGINSDIR\Splash_Splash.bmp" ".\bmp\splash.bmp"
    
80.   ; 使用闪屏插件显示闪屏
    
81.   advsplash::show 1500 600 400 -1 "$PLUGINSDIR\Splash_Splash"
    
82.   Pop $0 ; $0 返回 '1' 表示用户提前关闭闪屏, 返回 '0' 表示闪屏正常结束, 返回 '-1' 表示闪屏显示出错
    
83.   ;!insertmacro MUI_LANGDLL_DISPLAY
    
84.   StrCpy $INSTDIR "C:\Program Files\August\YoakemaeyoriRuriirona"
    
85.   ; Insert the NSISBASS_INIT macro
    
86.   !insertmacro NSISBASS_INIT
    
87.   ; We can extract a song file as well (so you got something to play).
    
88.   File "/oname=$PLUGINSDIR\tempsong.mp3" ".\music\bgm.mp3"
    
89.   !insertmacro NSISBASS_PLAY "$PLUGINSDIR\tempsong.mp3"
    
90. FunctionEnd
    
91. 
    
92. Var /GLOBAL dirStatus
    
93. 
    
94. Section "MainSection" SEC01
    
95. ;-------------------------backup----------------------------
    
96.   DetailPrint "正在备份文件..."
    
97.   CreateDirectory "$INSTDIR\backup"
    
98.   SetOverwrite on
    
99.   SetOutPath "$INSTDIR\backup"
    
100.   CopyFiles /SILENT "$INSTDIR\sysgrp.arc" "$INSTDIR\backup"
     
101.   CopyFiles /SILENT "$INSTDIR\sysprg.arc" "$INSTDIR\backup"
     
102.   CopyFiles /SILENT "$INSTDIR\system.arc" "$INSTDIR\backup"
     
103.   CopyFiles /SILENT "$INSTDIR\arc63.arc" "$INSTDIR\backup"
     
104. ;--------------------------copy----------------------------
     
105.   SetOutPath "$INSTDIR"
     
106.   DetailPrint "正在复制文件..."
     
107.   SetOverwrite ifnewer
     
108.   File ".\files\BGI_CHS.exe"
     
109.   SetOverwrite on
     
110.   File ".\files\arc00.arc"
     
111.   File ".\files\arc63.arc"
     
112.   File ".\files\sysgrp.arc"
     
113.   File ".\files\sysprg.arc"
     
114.   File ".\files\system.arc"
     
115.   ${DirState} "$INSTDIR\UserData" $dirStatus
     
116.   StrCmp $dirStatus "-1" nosavedata donesavedata
     
117.   nosavedata:
     
118.     CreateDirectory "$INSTDIR\UserData"
     
119.   donesavedata:
     
120. SectionEnd
     
121. 
     
122. Section "Add Start Menu Shortcuts" SEC02
     
123.   ; shortcuts
     
124.   !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
     
125.   SetOutPath "$INSTDIR"
     
126.   CreateDirectory "$SMPROGRAMS\$ICONS_GROUP"
     
127.   CreateShortCut "$SMPROGRAMS\$ICONS_GROUP\更胜黎明前的琉璃色 汉化版.lnk" "$INSTDIR\BGI_CHS.exe"
     
128.   CreateShortCut "$DESKTOP\更胜黎明前的琉璃色 汉化版.lnk" "$INSTDIR\BGI_CHS.exe"
     
129.   !insertmacro MUI_STARTMENU_WRITE_END
     
130. SectionEnd
     
131. 
     
132. Section -AdditionalIcons
     
133.   !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
     
134.   CreateShortCut "$SMPROGRAMS\$ICONS_GROUP\卸载简体中文补丁.lnk" "$INSTDIR\uninst.exe"
     
135.   !insertmacro MUI_STARTMENU_WRITE_END
     
136. SectionEnd
     
137. 
     
138. Section -Post
     
139.   WriteUninstaller "$INSTDIR\uninst.exe"
     
140.   WriteRegStr HKLM "${PRODUCT_DIR_REGKEY}" "" "$INSTDIR\bmw_chs.exe"
     
141.   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
     
142.   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
     
143.   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayIcon" "$INSTDIR\bmw_chs.exe"
     
144.   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
     
145.   WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "Publisher" "${PRODUCT_PUBLISHER}"
     
146. SectionEnd
     
147. 
     
148. 
     
149. Function un.onUninstSuccess
     
150.   HideWindow
     
151.   MessageBox MB_ICONINFORMATION|MB_OK "「更胜黎明前的琉璃色 汉化补丁」已成功地从你的计算机删除。"
     
152. FunctionEnd
     
153. 
     
154. Function un.onInit
     
155. !insertmacro MUI_UNGETLANGUAGE
     
156.   MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "你确实要完全删除「更胜黎明前的琉璃色 汉化补丁」，其及所有組件？" IDYES +2
     
157.   Abort
     
158. FunctionEnd
     
159. 
     
160. Section Uninstall
     
161.   !insertmacro MUI_STARTMENU_GETFOLDER "Application" $ICONS_GROUP
     
162. ;----------------------delete_files------------------------
     
163.   Delete "$INSTDIR\uninst.exe"
     
164.   Delete "$INSTDIR\arc00.arc"
     
165.   Delete "$INSTDIR\arc63.arc"
     
166.   Delete "$INSTDIR\BGI_CHS.exe"
     
167. ;--------------------delete_shortcuts----------------------
     
168.   Delete "$SMPROGRAMS\$ICONS_GROUP\更胜黎明前的琉璃色 汉化版.lnk"
     
169.   Delete "$SMPROGRAMS\$ICONS_GROUP\卸载简体中文补丁.lnk"
     
170.   Delete "$DESKTOP\更胜黎明前的琉璃色 汉化版.lnk"
     
171.   RMDir "$SMPROGRAMS\$ICONS_GROUP"
     
172. ;------------------restore_backup_files--------------------
     
173.   SetOverwrite on
     
174.   CopyFiles "$INSTDIR\backup\arc63.arc" "$INSTDIR"
     
175.   CopyFiles "$INSTDIR\backup\sysgrp.arc" "$INSTDIR"
     
176.   CopyFiles "$INSTDIR\backup\sysprg.arc" "$INSTDIR"
     
177.   CopyFiles "$INSTDIR\backup\system.arc" "$INSTDIR"
     
178.   RMDir /r "$INSTDIR\backup"
     
179. ;-----------------delete_uninst_reg_keys-------------------
     
180.   DeleteRegKey ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}"
     
181.   DeleteRegKey HKLM "${PRODUCT_DIR_REGKEY}"
     
182. ;--------------------close_after_unist---------------------
     
183.   SetAutoClose true
     
184. SectionEnd

复制代码