正式会员享受无限制浏览网站功能和高速网盘下载,赶快加入本站吧!
您需要 登录 才可以下载或查看,没有账号?立即注册
x
- ; gifctrl.dll 为一个用于 Inno Setup 的 12 KB 的 gif 显示插件,同样可以显示 BMP 和 JPEG。
- [Setup]
- AppName=我的程序
- AppVerName=我的程序 版本 1.5
- DefaultDirName={pf}\我的程序
- DefaultGroupName=我的程序
- UninstallDisplayIcon={app}\MyProg.exe
- Compression=lzma
- [Files]
- Source: "MyProg.exe"; DestDir: "{app}"
- Source: "Readme.txt"; DestDir: "{app}"; Flags: isreadme
- Source: "gifctrl.dll"; Flags: dontcopy
- Source: nsisinstall.gif; DestDir: {app}; Flags: dontcopy
- [Icons]
- Name: "{group}\我的程序"; Filename: "{app}\MyProg.exe"
- [code]
- const
- HALIGN_CENTER = 0; //水平居中
- HALIGN_LEFT = 1; //水平靠左
- HALIGN_RIGHT = 2; //水平靠右
- VALIGN_CENTER = 0; //垂直居中
- VALIGN_TOP = 1; //垂直靠上
- VALIGN_BOTTOM = 2; //垂直靠下
- FIT_NONE = 0; //不适应窗口
- FIT_WIDTH = 1; //适应窗口宽度
- FIT_HEIGHT = 2; //适应窗口高度
- FIT_BOTH = 3; //适应窗口宽度和高度
-
- CLR_INVALID = $FFFFFFFF; //自动取容器左上角的颜色作为底色,如果取色失败,用按钮颜色代替。
- function playgif(GifHandle: HWND; HAlign: integer; VAlign: integer; BGColor: DWord;
- Fit: integer; GifFileName: PChar): BOOL; external 'playgif@files:gifctrl.dll stdcall';
- //GifHandle 放置图片的容器,一般用 TPanel 装载图片就可以了。
- //HAlign 水平放置位置
- //VAlign 垂直放置位置
- //BGColor 背景颜色
- //Fit 适应窗口大小
- //GifFileName 图片文件名
- function stopgif(): BOOL; external 'stopgif@files:gifctrl.dll stdcall';
- //释放Gif显示
- var
- GifPanel: TPanel;
- procedure InitializeWizard();
- var
- GifFileName: String;
- begin
- ExtractTemporaryFile('nsisinstall.gif');
-
- GifPanel := TPanel.Create(WizardForm);
- GifPanel.Parent := WizardForm.InstallingPage;
- GifPanel.Caption := '';
- GifPanel.Top := WizardForm.PROGRESSGAUGE.Top + WizardForm.PROGRESSGAUGE.Height + 5;
- GifPanel.Left := 0;
- GifPanel.Width := WizardForm.InstallingPage.Width;
- GifPanel.Height := WizardForm.InstallingPage.Height - (WizardForm.PROGRESSGAUGE.Top
- + WizardForm.PROGRESSGAUGE.Height + 5);
-
- playgif(GifPanel.Handle, HALIGN_CENTER, VALIGN_BOTTOM, CLR_INVALID, FIT_WIDTH,
- ExpandConstant('{tmp}\nsisinstall.gif'));
- end;
- procedure DeinitializeSetup();
- begin
- stopgif();
- end;
- procedure CurPageChanged(CurPageID: Integer);
- begin
- if CurPageID = wpInstalling then
- begin
- MsgBox('暂停一下,看看效果。', mbInformation, MB_OK);
- end;
- end;
复制代码
|