Nsis 带 SimpleSC 脚本

Share

1. # NetHalt - NSIS installer script
   
2. # Copyright (C) 2008 Daniel Collins <solemnwarning@solemnwarning.net>
   
3. # All rights reserved.
   
4. #
   
5. # Redistribution and use in source and binary forms, with or without
   
6. # modification, are permitted provided that the following conditions are met:
   
7. #
   
8. #    * Redistributions of source code must retain the above copyright
   
9. #      notice, this list of conditions and the following disclaimer.
   
10. #
    
11. #    * Redistributions in binary form must reproduce the above copyright
    
12. #      notice, this list of conditions and the following disclaimer in the
    
13. #      documentation and/or other materials provided with the distribution.
    
14. #
    
15. #    * Neither the name of the author nor the names of its contributors may
    
16. #      be used to endorse or promote products derived from this software
    
17. #      without specific prior written permission.
    
18. #
    
19. # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY
    
20. # EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
    
21. # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
    
22. # DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY
    
23. # DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
    
24. # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
    
25. # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
    
26. # ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
    
27. # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
    
28. # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
    
29. 
    
30. !include MUI2.nsh
    
31. !include LogicLib.nsh
    
32. !include nsDialogs.nsh
    
33. 
    
34. Name "NetHalt"
    
35. OutFile "nhclient.exe"
    
36. 
    
37. InstallDir $PROGRAMFILES\NetHalt
    
38. InstallDirRegKey HKLM "SOFTWARE\NetHalt" "InstallDir"
    
39. 
    
40. !define MUI_ABORTWARNING
    
41. 
    
42. !insertmacro MUI_PAGE_WELCOME
    
43. !insertmacro MUI_PAGE_LICENSE "COPYING"
    
44. !insertmacro MUI_PAGE_DIRECTORY
    
45. !insertmacro MUI_PAGE_INSTFILES
    
46. 
    
47. !insertmacro MUI_LANGUAGE "English"
    
48. 
    
49. Function .onInit
    
50.     nsisos::osversion
    
51.    
    
52.     ${If} $0 < 5
    
53.         MessageBox MB_OK "Windows 2000 (NT 5.0) or greater is required"
    
54.         Abort
    
55.     ${EndIf}
    
56. FunctionEnd
    
57. 
    
58. # Do local install
    
59. #
    
60. Section "NetHalt"
    
61.     SetShellVarContext all
    
62.     SetOutPath $INSTDIR
    
63.    
    
64.     # Stop all running nhtray.exe processes
    
65.     #
    
66.     StrCpy $0 "nhtray.exe"
    
67.     KillProc::KillProcesses
    
68.    
    
69.     # Check if the NetHalt service is installed
    
70.     #
    
71.     SimpleSC::ExistsService "nhclient"
    
72.     Pop $0
    
73.    
    
74.     # Stop+Remove the NetHalt service if it's installed
    
75.     #
    
76.     ${If} $0 == 0
    
77.         DetailPrint "Stopping NetHalt Client service..."
    
78.         SimpleSC::StopService "nhclient"
    
79.         
    
80.         DetailPrint "Removing NetHalt Client service..."
    
81.         SimpleSC::RemoveService "nhclient"
    
82.     ${EndIf}
    
83.    
    
84.     WriteRegStr HKLM "SOFTWARE\NetHalt" "InstallDir" $INSTDIR
    
85.    
    
86.     cinst::reg_write "dword" "SOFTWARE\NetHalt" "use_server" "0"
    
87.     cinst::reg_write "string" "SOFTWARE\NetHalt" "server_name" ""
    
88.     cinst::reg_write "dword" "SOFTWARE\NetHalt" "server_port" "0"
    
89.     cinst::reg_write "dword" "SOFTWARE\NetHalt" "server_refresh" "1800"
    
90.    
    
91.     cinst::reg_write "dword" "SOFTWARE\NetHalt" "warning" "300"
    
92.     cinst::reg_write "dword" "SOFTWARE\NetHalt" "abort" "0"
    
93.     cinst::reg_write "dword" "SOFTWARE\NetHalt" "delay" "0"
    
94.     cinst::reg_write "string" "SOFTWARE\NetHalt" "sdtimes" ""
    
95.    
    
96.     WriteUninstaller "$INSTDIR\uninstall.exe"
    
97.    
    
98.     File "src\nhclient.exe"
    
99.     File "src\evlog.dll"
    
100.     File "src\nhtray.exe"
     
101.     File "src\nhconfig.exe"
     
102.    
     
103.     # Add the event log source (evlog.dll) to the registry
     
104.     #
     
105.     WriteRegStr HKLM "SYSTEM\CurrentControlSet\Services\Eventlog\Application\NetHalt Client" "EventMessageFile" "$INSTDIR\evlog.dll"
     
106.     WriteRegDWORD HKLM "SYSTEM\CurrentControlSet\Services\Eventlog\Application\NetHalt Client" "TypesSupported" 0x00000007
     
107.    
     
108.     # Add the uninstaller to Add/Remove programs
     
109.     #
     
110.     WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\NetHalt" "DisplayName" "NetHalt"
     
111.     WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\NetHalt" "UninstallString" "$INSTDIR\uninstall.exe"
     
112.     WriteRegDWORD HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\NetHalt" "NoModify" 1
     
113.     WriteRegDWORD HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\NetHalt" "NoRepair" 1
     
114.    
     
115.     # Install and start the NetHalt service
     
116.     # TODO: Check for errors
     
117.     #
     
118.     DetailPrint "Installing NetHalt Client service..."
     
119.     SimpleSC::InstallService "nhclient" "NetHalt Client" "16" "2" "$INSTDIR\nhclient.exe" "" "" ""
     
120.    
     
121.     DetailPrint "Starting NetHalt Client service..."
     
122.     SimpleSC::StartService "nhclient"
     
123.    
     
124.     # Add nhtray.exe to the registry to run at login
     
125.     #
     
126.     WriteRegStr HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "NetHalt" "$INSTDIR\nhtray.exe"
     
127.    
     
128.     # Launch nhtray.exe
     
129.     #
     
130.     Exec '"$INSTDIR\nhtray.exe"'
     
131.    
     
132.     # Create shortcuts
     
133.     #
     
134.     CreateDirectory "$SMPROGRAMS\NetHalt"
     
135.     CreateShortCut "$SMPROGRAMS\NetHalt\Tray Icon.lnk" "$INSTDIR\nhtray.exe"
     
136.     CreateShortCut "$SMPROGRAMS\NetHalt\Configuration.lnk" "$INSTDIR\nhconfig.exe"
     
137.     CreateShortCut "$SMPROGRAMS\NetHalt\Uninstall.lnk" "$INSTDIR\uninstall.exe"
     
138. SectionEnd
     
139. 
     
140. Function un.onInit
     
141.     SetShellVarContext all
     
142.     ReadRegStr $INSTDIR HKLM "SOFTWARE\NetHalt" "InstallDir"
     
143.    
     
144.     MessageBox MB_YESNO "This will uninstall NetHalt, continue?" IDYES NoAbort
     
145.     Abort
     
146.     NoAbort:
     
147. FunctionEnd
     
148. 
     
149. Section "Uninstall"
     
150.     # Stop and remove the NetHalt service
     
151.     #
     
152.     DetailPrint "Stopping NetHalt Client service..."
     
153.     SimpleSC::StopService "nhclient"
     
154.    
     
155.     DetailPrint "Removing NetHalt Client service..."
     
156.     SimpleSC::RemoveService "nhclient"
     
157.    
     
158.     # Stop all running nhtray.exe processes
     
159.     #
     
160.     StrCpy $0 "nhtray.exe"
     
161.     KillProc::KillProcesses
     
162.    
     
163.     # Delete shortcuts
     
164.     #
     
165.     Delete "$SMPROGRAMS\NetHalt\Tray Icon.lnk"
     
166.     Delete "$SMPROGRAMS\NetHalt\Configuration.lnk"
     
167.     Delete "$SMPROGRAMS\NetHalt\Un-Install.lnk"
     
168.     Delete "$SMPROGRAMS\NetHalt"
     
169.    
     
170.     DeleteRegValue HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Run" "NetHalt"
     
171.     DeleteRegKey HKLM "SYSTEM\CurrentControlSet\Services\Eventlog\Application\NetHalt Client"
     
172.     DeleteRegKey HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\NetHalt"
     
173.    
     
174.     Delete "$INSTDIR\nhclient.exe"
     
175.     Delete "$INSTDIR\evlog.dll"
     
176.     Delete "$INSTDIR\nhtray.exe"
     
177.     Delete "$INSTDIR\uninstall.exe"
     
178.     RMDir $INSTDIR
     
179. SectionEnd
     
180. 
     

复制代码